OnSynchronizePackingStations

Use this event to

Optional:  Synchronize master data for Package Stations from 3rd party Shipping App to Pack and Ship

Description

Package Stations is an optional entity in the "Pack and Ship" setup.  The "Pack and Ship" solution has no functionality attached to "Packing Station"s out-of-the box and syncronizing Packing Stations is entirely optional.

A sample use can be seen in our "ShipIt365 Connector" where the "MOS Packing Station" table is extended with new fields for external user names to be sent to the "Transsmart" service used by the "IDYS ShipIt365 AppSource App". Unless you have extended the "MOS Packing Station" table with your own custom fields it will generally not be needed to syncronize master data for this table.

See also: Read Master Data From Shipping Provider

Template

    [EventSubscriber(ObjectType::Codeunit, Codeunit::"MOS Pack API", 'OnSynchronizePackingStations', '', true, true)]
    local procedure OnSynchronizePackingStations(var _PackingStation: Record "MOS Packing Station")
    begin
    end;

Example

    [EventSubscriber(ObjectType::Codeunit, Codeunit::"MOS Pack API", 'OnSynchronizePackingStations', '', true, true)]
    local procedure OnSynchronizePackingStations(var _PackingStation: Record "MOS Packing Station")
    var
        IdysUserSetup: Record "IDYS User Setup";
    begin
        IdysUserSetup.Reset();
        if IdysUserSetup.FindSet() then
            repeat
                _PackingStation.SetRange("MOSSHIPIT User Name (External)", IdysUserSetup."User Name (External)");
                if _PackingStation.IsEmpty() then begin
                    _PackingStation.Init();
                    _PackingStation."No." := '';  // Auto-assigned in OnInsert( ) if blank.
                    _PackingStation.Description := IdysUserSetup."User Name (External)";
                    _PackingStation."MOSSHIPIT User Name (External)" := IdysUserSetup."User Name (External)";
                    _PackingStation.Insert(true);
                end;
            until IdysUserSetup.Next() = 0;

        _PackingStation.Reset();  // Remove any filters
    end;

tableextension 62100 "MOSSHIPIT Packing Station" extends "MOS Packing Station"
{
    fields
    {
        field(62100; "MOSSHIPIT User Name (External)"; Text[80])
        {
            Caption = 'User Name (External)';
            DataClassification = ToBeClassified;
        }       
    }
}

Version History